#!/usr/bin/perl
use strict;
use warnings;

use File::Glob ':glob';

my($install_dir_logical) = 'C:';
my($scriptname) = 'install_script.iss';

if($#ARGV > 0) {
    print "Usage: $0 > [install script.sh]\n";
    print "Run from the directory innounp.exe created $scriptname into.\n";
    print "Once run, you can review the generated shell install script\n";
    print "Finally, run install script with target install directory as parameter\n";
    print "(the directory your windows fake C: drive lives in).\n";
    exit 1;
}

my $date = `date +'%F %T'`;
chomp $date;

my $defaultdirname;
my $defaultdirname_logical;
my $current_subkey = '<None>';

my $setup_section = 0;
my $files_section = 0;
my $registry_section = 0;

sub eval_check {
    my($check) = @_;
#    print STDERR "<$check>";
     my(%atoms) = (
# What environment do we emulate? Should be configurable with parameters...
	'IsWinXP' => 1,
	'IsVISTA' => 0,
	'IsWindows7' => 0,

	'IsWindows32' => 1,
	'IsWindows64' => 0,
	);
    $check =~ s@\band\b@&&@gi;
    while(my($key, $value) = each(%atoms)) {
	$check =~ s@\b$key\b@$value@egi;
    }
#    print STDERR "=> <$check>\n";
    eval $check;
}

sub esc_chars {
    # will change, for example, a!!a to a\!\!a
    $_[0] =~ s/([;<>\*\|`&\$!#\(\)\[\]\{\}:'" ])/\\$1/g;
    return $_[0];
}

sub any_case {
    my($filename) = @_;
    $filename =~ s@([a-zA-Z])@"[".lc($1).uc($1)."]"@ge;
    $filename;
}

my(%created_dirs_cache) = ();

open(SCRIPT, '<', $scriptname) or die "$scriptname not found";
print <<'EOF';
#/bin/sh -x
INSTALL_DIR="$1"
if [ ! -d "$INSTALL_DIR" -o ! -d "$INSTALL_DIR/windows" -o ! -d "$INSTALL_DIR/Program Files" ]; then
  echo "Usage: $0 [install dir]"
  exit 1
fi

EOF
while(defined(my $line = <SCRIPT>)) {
    $line =~ s/[\n\r]+$//;
#    print STDERR "# $line\n";
    if($line =~ /^\[.*\]$/) {
	if($registry_section) {
	    print "EOF\n";
	}
	$setup_section = $files_section = $registry_section = 0;
	$setup_section = 1 if $line eq '[Setup]';
	$files_section = 1 if $line eq '[Files]';
	$registry_section = 1 if $line eq '[Registry]';
	if($registry_section) {
	    print "cat > \"\$INSTALL_DIR\"/install.reg <<'EOF'\nREGEDIT4\n";
	}
    }
    if($setup_section && $line =~ /^DefaultDirName=(.*)$/) {
	$defaultdirname = $defaultdirname_logical = $1;
	$defaultdirname =~ s@\\@/@g;
	$defaultdirname =~ s@\{pf\}@\$INSTALL_DIR/Program Files@;
	$defaultdirname_logical =~ s@\{pf\}@${install_dir_logical}."\\Program Files"@e;
    }
    if($files_section && $line =~ /^Source: "(.*?)"; DestDir: "(.*?)"; (?:DestName: "(.*?)"; )?(?:Components: "(.*?)"; )?(?:Flags: (.*))?$/) {
	my($source, $destdir, $destname, $components, $flags) = ($1, $2, $3, $4, $5);
	$flags = '' unless defined $flags;
	if($flags !~ /dontcopy/) {
	    $source =~ s@\\@/@g;
	    if(!-f $source) {
		my($quoted_source) = $source;
		$quoted_source =~ s/([[\]{}\\*?~])/\\$1/g;
		my(@list) = bsd_glob(any_case($quoted_source), GLOB_QUOTE | GLOB_NOSORT);
		if(scalar @list == 1) {
		    print STDERR "Fixing source filename `$source' as `$list[0]'\n";
		    $source = $list[0];
		}
	    }
	    if(-f $source) {
		$destdir =~ s@\\@/@g;
		$destdir =~ s@\{tmp\}@\$INSTALL_DIR/windows/temp@;
		$destdir =~ s@\{sys\}@\$INSTALL_DIR/windows/system@;
		$destdir =~ s@\{app\}@$defaultdirname@e;
		$destdir =~ s@\{commondocs\}@\$INSTALL_DIR/users/Public/Documents@;
		$destdir =~ s@\{userdocs\}@\$INSTALL_DIR/users/crossover/Documents@;

		if(!$destname) {
		    $destname = $source;
		    $destname =~ s@^.*/@@g;
		}

		my($target) = "$destdir/$destname";

		if(!exists $created_dirs_cache{$destdir}) {
		    print "mkdir -p \"$destdir\"\n";
		    $created_dirs_cache{$destdir} = 1;
		}
		if($flags =~ /onlyifdoesntexist/) {
		    print "[ -f \"$target\" ] || ";
		}
		print "cp -av ".esc_chars($source)." \"$target\"\n";
	    }
	    elsif ($flags !~ /skipifsourcedoesntexist/) {
		die "Source file $source missing";
	    }
	}
    }
    if ($registry_section) {
	if ($line =~ /^Root: ([^;]*?); Subkey: "(.*?)"; ValueName: "(.*?)"; ValueType: ([^;]*?); (?:ValueData: "(.*?)"; )?(?:Components: "(.*?)"; )?(?:Check: "(.*?)"; )?(?:Flags: (.*))?$/) {
	    my($root, $subkey, $valuename, $valuetype, $valuedata, $components, $check, $flags) = ($1, $2, $3, $4, $5, $6, $7);
	    $valuedata = '' unless defined $valuedata;
	    $check = '' unless defined $check;
	
	    if($check eq '' || eval_check($check)) {
		my(%root_map) = (
		    'HKLM' => 'HKEY_LOCAL_MACHINE',
		    'HKLM64' => 'HKEY_LOCAL_MACHINE',
		    'HKCU' => 'HKEY_CURRENT_CONFIG',
		    );
		die "Don't know how to handle registry root $root" if !exists $root_map{$root};
		my $full_subkey = "$root_map{$root}\\$subkey";
		if($current_subkey ne $full_subkey) {
		    print "\n[$full_subkey]\n";
		    $current_subkey = $full_subkey;
		}
		my(%value_map) = (
		    'String' => sub { my($string) = @_; $string =~ s/\\/\\\\/g; "\"$string\"" },
		    'Dword' => sub { my($dword) = @_; $dword =~ s/^\$//; "dword:$dword" },
		    );
		die "Don't know how to handle registry value type $valuetype" if !exists $value_map{$valuetype};
		$valuename =~ s@\{tmp\}@${install_dir_logical}."\\windows\\temp"@e;
		$valuename =~ s@\{sys\}@${install_dir_logical}."\\windows\\system"@e;
		$valuename =~ s@\{app\}@$defaultdirname_logical@e;
		$valuename =~ s@\{commondocs\}@${install_dir_logical}."\\users\\Public\\Documents"@;
		$valuename =~ s@\{userdocs\}@\${install_dir_logical}."\\users\\crossover\\Documents"@;
		$valuedata =~ s@\{tmp\}@${install_dir_logical}."\\windows\\temp"@e;
		$valuedata =~ s@\{sys\}@${install_dir_logical}."\\windows\\system"@e;
		$valuedata =~ s@\{app\}@$defaultdirname_logical@e;
		$valuedata =~ s@\{commondocs\}@${install_dir_logical}."\\users\\Public\\Documents"@;
		$valuedata =~ s@\{userdocs\}@\${install_dir_logical}."\\users\\crossover\\Documents"@;
		$valuedata =~ s@\{code:GetCurrentDataTime\}@$date@e;
		print "\"$valuename\"=".(&{$value_map{$valuetype}}($valuedata))."\n";
	    }
	}
	else {
#	    print STDERR "Registry line parse error: `$line'\n"
	}
    }
}
close(SCRIPT);
print "echo \"Don't forget to import C:\\install.reg from within your environment using regedit\"\n";