-- Quest: C:\QUESTS\WORKING\L0B00Y02.Qbn.
-- StartsBy: NPC
-- Questee: member
-- Questor: Brotherhood
-- Repute: 0
-- QuestId: 2
-- Edited for Daggerfall Unity by Jay_H
Messages: 16
Quest: L0B00Y02
DisplayName: Disagreeable Competition
-- Message panels
QRC:

QuestorOffer:  [1000]
<ce>                 There is another assassination group
<ce>                      budding in %reg, which must
<ce>                 be crushed before it can bloom. I want
<ce>                 you to move in, account the assassin,
<ce>                 and then the man or woman who ordered
<ce>                  the assassination. You do have time
<ce>                        for this endeavor, yes?
                                     <--->
<ce>                 The Dark Brotherhood has been the sole
<ce>                 assassin's guild in Tamriel since the
<ce>                   Second Era. We intend to keep that
<ce>                monopoly. There is a freelance assassin
<ce>                who has been flaunting us for some time,
<ce>                         but =assassin_'s luck
<ce>                  has ended. I want you to teach %g2 a
<ce>                 permanent lesson, and then repeat the
<ce>                    lesson for %g3 foolish employer.

RefuseQuest:  [1001]
<ce>                    No? How strange and troubling.

AcceptQuest:  [1002]
<ce>                   Good. Now then, we know that the
<ce>                         assassin, =assassin_,
<ce>                  has pursued %g3 quarry to a dungeon
<ce>                         called ___mondung_. If
<ce>                  you have not found any clues to the
<ce>                  employer's wherebouts, return here.
<ce>                   I would, of course, prefer for you
<ce>                         to account =assassin_
<ce>                   and %g3 employer both, but I'd be
<ce>                    reasonably satisfied with merely
<ce>                    the freelancer's death. Take no
<ce>                     longer than =queston_ days for
<ce>                           both accountings.

QuestComplete:  [1004]
<ce>                       Excellent, %pct. We would
<ce>               have been happy with just the termination
<ce>                       of =assassin_, but now the
<ce>                        acquaintances of =boss_
<ce>                will know that the Dark Brotherhood does
<ce>                 not take well to amateur competition.

RumorsDuringQuest:  [1005]
That =assassin_ has been a freelance assassin in %reg for years now.
<--->
=assassin_ isn't the best in the business, but %g has a lot of enthusiasm.

RumorsPostfailure:  [1006]
=assassin_ just proves you can work outside of the Brotherhood.
<--->
Apparently the Brotherhood can't stop all the freelancers in Tamriel.

RumorsPostsuccess:  [1007]
=boss_ thought %g could save a few gold pieces by hiring =assassin_ ... idiot.
<--->
It just doesn't pay to use assassins other than the Brotherhood, ask =boss_.

QuestorPostsuccess:  [1008]
And how are you, slayer of the rogue _assassin_?

QuestorPostfailure:  [1009]
<ce>             You're that worthless thug who can't account
<ce>                 a bumbling freelancer like =assassin_.
<ce>                  Why should I waste my breath on you?

QuestLogEntry:  [1010]
%qdt:
 _qgiver_ of the Dark
 Brotherhood in ___qgiver_
 has me paying a visit on =assassin_,
 a competing assassin, where %g is completing a contract
 in ___mondung_. If I can find any
 clues about =assassin_'s employer,
 I am to account him or her also.
 Either way, the whole bloody business needs
 to be done in =queston_ days.

Message:  1011
After slaying %n,
 go to ___stronghold_ in
 the wilderness of %reg
 for your reward.
 
 
 =boss_

Message:  1012
%qdt:
 I found a note on =assassin_'s body.
 %g3 employer is =boss_, and %g3
 stronghold is ___stronghold_.

Message:  1013
<ce>                      You have slain =assassin_.
<ce>                    The Brotherhood will be pleased.

Message:  1014
<ce>                    =boss_ has joined %g3 employee.
<ce>                    The Brotherhood will be pleased.

Message:  1015
<ce>                 We would have preferred it if you had
<ce>                         accounted =assassin_'s
<ce>                 boss as well. But it's enough to know
<ce>                         that =assassin_ can no
<ce>                    longer be counted as part of the
<ce>                              competition.


-- Symbols used in the QRC file:
--
--                %g occurs 3 times.
--               %g2 occurs 1 time.
--               %g3 occurs 10 times.
--                %n occurs 1 time.
--              %pct occurs 1 time.
--              %qdt occurs 2 times.
--              %reg occurs 9 times.
--        =assassin_ occurs 15 times.
--            =boss_ occurs 50 times.
--         =queston_ occurs 3 times.
--                 _ occurs 1 time.
--       ___mondung_ occurs 2 times.
--        ___qgiver_ occurs 1 time.
--    ___stronghold_ occurs 3 times.
--         __qgiver_ occurs 1 time.
--        _assassin_ occurs 1 time.
--          _qgiver_ occurs 1 time.

QBN:
Item _letter_ letter used 1011

Person _qgiver_ face 110 group Questor

Place _mondung_ remote dungeon
Place _stronghold_ remote dungeon2

Clock _queston_ 00:00 0 flag 17 range 0 5

Foe _assassin_ is Assassin
Foe _boss_ is Knight

--	Quest start-up:
	start timer _queston_ 
	reveal _mondung_ 
	log 1010 step 0 
	give item _letter_ to _assassin_ 
	_letter_ used do _S.05_ 
	place foe _boss_ at _stronghold_ 
	place foe _assassin_ at _mondung_ 

_queston_ task:
	end quest 

_qgclicked_ task:
	clicked npc _qgiver_ 

variable _reward_
_S.03_ task:
	killed 1 _assassin_ 
	say 1013 

_S.04_ task:
	killed 1 _boss_ 
	say 1014 

_S.05_ task:
	reveal _stronghold_ readmap
	log 1012 step 1 

_S.06_ task:
	when _S.03_ and not _S.04_ and _qgclicked_ 
	say 1015 

_S.07_ task:
	when _S.03_ and _S.04_ and _qgclicked_ 
	give pc nothing 
	end quest 

_S.08_ task:
	when not _S.03_ and not _S.04_ and _qgclicked_ 
	clear _qgclicked_ _S.08_ 
