-- Quest: C:\QUESTS\WORKING\30C00Y00.Qbn.
-- StartsBy: NPC
-- Questee: anyone
-- Questor: Namira
-- Repute: 0
-- QuestId: 0
-- Edited for Daggerfall Unity by Jay_H
Messages: 31
Quest: 30C00Y00
DisplayName: Namira's Quest
-- Message panels
QRC:

QuestorOffer:  [1000]
<ce>          The desire for power gnaws at the gut, does it not,
<ce>            %pcf? I can see it does. Excuse my informality,
<ce>          but I feel like I know you, I recognize your craving
<ce>           as if it were my own. You want to control, and the
<ce>          thought makes you slaver like a starving wolf. I can
<ce>          fill your belly, but first, I need to know. Will you
<ce>                    kill in order to fill this void?

RefuseQuest:  [1001]
<ce>             No?! Now you taunt me, %pcf. You tempt me out
<ce>            of my dark palace and then shun my company. If I
<ce>          thought you were merely being cruel, I could respect
<ce>            it. But I suspect that you are actually stupid,
<ce>           which I cannot abide. Therefore, I bid you a most
<ce>                           disgusted goodbye.

AcceptQuest:  [1002]
<ce>           Wonderful. You should see the look in your eyes,
<ce>            %pcf. You will be mighty, I can see it in them.
<ce>            Now, your stepping stone to power is a vampiric
<ce>               ancient who has displeased me, =monster_.
<ce>              Know that %g is a mighty adversary, and %g3
<ce>                      asylum, ___mondung_, is well
<ce>             protected. But you can and will kill %g2. Once
<ce>                   you have, go to my darling friend,
<ce>                     _qgfriend_ over at __qgfriend_
<ce>                      in ___qgfriend_. _qgfriend_
<ce>            is a busy person, so don't keep %g2 waiting more
<ce>              than =1stparton_ days. _qgfriend_ will have
<ce>              a present for you that I think will make you
<ce>                very happy. Farewell, %pcf. We will meet
<ce>                             again, I know.

QuestFail:  [1003]
<ce>            While that vampire ancient still lives, we have
<ce>                      nothing to talk about, %pcf.

QuestComplete:  [1004]
<ce>                     Hello, %pcn. I am _qgfriend_.
<ce>            You look ... sated. That murder agreed with you,
<ce>            I think. Well, I hope this will likewise please.
<ce>             Namira told me to give you her ring. Try it on
<ce>              and you will learn the meaning of hunger and
<ce>               fulfillment. Once you know that, you know
<ce>                         power. Good day, %pcf.

RumorsDuringQuest:  [1005]
There's a vampire in ___mondung_ that is so old, it doesn't drink blood anymore.
<--->
They say the vampire in ___mondung_ has learned to control its bloodlust.

RumorsPostfailure:  [1006]
The vampire in ___mondung_ apparently decided that it was time to move on.
<--->
I guess that vampire did still need blood after all. It left for some reason.

RumorsPostsuccess:  [1007]
I don't care if that vampire did conquer its bloodlust: I'm glad it's dead.
<--->
The stars of Namira burned bright last night. Always hungry, never satisfied.

Message:  1011
_qgfriend_ is that =qgfriend_ over in __qgfriend_, I think. Yes, %di of here.
<--->
_qgfriend_ is the name of the =qgfriend_ in __qgfriend_. Look to the %di.

Message:  1012
_qgfriend_ is a Gourmand in the service of Namira, Daedra Prince of Hunger.
<--->
_qgfriend_ is the name of one of the Gourmands in the service of Namira.

Message:  1013
Pain inflicted on the Ring's wearer is reflected back on the attacker.

Message:  1020
%qdt:
 The Daedra Prince Namira has promised me
 _artifact_, if I will kill the vampire
 =monster_ for her within =1stparton_ days.
 Her contact _qgfriend_ won't wait any
 longer than that for me in __qgfriend_
 of ___qgfriend_, so I cannot be late. The
 vampire supposedly lives in ___mondung_.

Message:  1030
<ce>                  =monster_ is dead.  Namira's hunger
<ce>                  is sated -- now to satisfy your own
<ce>                  desires by reporting to _qgfriend_.


-- Symbols used in the QRC file:
--
--               %di occurs 2 times.
--                %g occurs 1 time.
--               %g2 occurs 5 times.
--               %g3 occurs 2 times.
--              %pcf occurs 10 times.
--              %pcn occurs 1 time.
--              %qdt occurs 1 time.
--       =1stparton_ occurs 2 times.
--         =monster_ occurs 3 times.
--        =qgfriend_ occurs 2 times.
--       ___mondung_ occurs 6 times.
--      ___qgfriend_ occurs 6 times.
--        _artifact_ occurs 1 time.
--        _qgfriend_ occurs 12 times.

QBN:
Item _artifact_ artifact Ring_of_Namira used 1013

Person _questgiver_ face 112 group Questor anyInfo 1013
Person _qgfriend_ group Librarian anyInfo 1011 rumors 1012

Place _mondung_ remote dungeon

Clock _1stparton_ 00:00 0 flag 1 range 2 5

Foe _monster_ is Ancient_vampire

--	Quest start-up:
	start timer _1stparton_ 
	reveal _mondung_ 
	log 1020 step 0 
	place foe _monster_ at _mondung_ 

_1stparton_ task:
	end quest 

-- _2ndparton_ removed as nonexistent task
_pcgetsgold_ task:
	when _npcclicked_ and _mondead_ 
	give pc _artifact_ 
	end quest 
--removed unnecessary delay

_mondead_ task:
	killed 1 _monster_ 
	say 1030 

_npcclicked_ task:
	clicked npc _qgfriend_ 

--defining clearclick to prevent out-of-place victory condition
_clearclick_ task:
	when _npcclicked_ and not _mondead_
	say 1003
	clear _npcclicked_ _clearclick_
