-- Quest: C:\QUESTS\WORKING\A0C01Y03.Qbn.
-- StartsBy: NPC
-- Questee: anyone
-- Questor: peasant
-- Repute: 01
-- QuestId: 3
Messages: 18
Quest: A0C01Y03
DisplayName: The Riddle
-- Message panels
QRC:

QuestorOffer:  [1000]
<ce>                       I am _qgiver_, and I need
<ce>                the services of a hunter of men. I am in
<ce>                      love with _spouse_. Alas, %g
<ce>             refuses to marry unless I prove my worthiness
<ce>                    by answering a riddle %g3 mentor
<ce>                 _hermit_ left behind when %g vanished.
<ce>               I need you to find %g2 and find the answer
<ce>               to %g3 riddle. I will pay you _gold_ gold
<ce>                         pieces if you succeed.

RefuseQuest:  [1001]
<ce>              I will continue my search for an adventurer
<ce>               willing to take up my charge. If you meet
<ce>                anyone who would be interested in such a
<ce>                    quest, direct them to _qgiver_.

AcceptQuest:  [1002]
<ce>                The only person who might help you find
<ce>                         _hermit_ is _spouse_.
<ce>                     %g can be found in ___spouse_.
<ce>              Take these flowers. They are %g3 favorites.
<ce>                 They may gain you some favor with %g2.
<ce>                    Here is a letter with _hermit_'s
<ce>               riddle inscribed upon it. If you have not
<ce>                returned in three months, I will assume
<ce>                         that you have failed.

QuestComplete:  [1004]
<ce>                  _qgiver_ rips open the letter from
<ce>                  _hermit_. "Kindness! Of course. Now
<ce>                  I understand why _spouse_ sent me on
<ce>               this quest. It is not enough to love %g2,
<ce>                I have to show %g2 kindness as well. You
<ce>                   have been most helpful, %pcf. Here
<ce>                      is the gold I promised you."

RumorsDuringQuest:  [1005]
<ce>                    _qgiver_ is smitten with love.
<ce>                   %g has been trying to get _spouse_
<ce>                to accept a marriage proposal for ages.

RumorsPostfailure:  [1006]
<ce>                     I hear that _spouse_ over in
<ce>                      ___spouse_ married. _qgiver_
<ce>                 will be heartbroken when %g finds out.

RumorsPostsuccess:  [1007]
<ce>                        Good news! _spouse_ and
<ce>                    _qgiver_ were married recently.

QuestorPostsuccess:  [1008]
<ce>                  Anything for the %ra that found the
<ce>                     answer to my riddle. _spouse_
<ce>                      and I are married, you know.

QuestorPostfailure:  [1009]
<ce>              You are the %ra that was unable to find the
<ce>              answer to the hermit's riddle. I have no use
<ce>                           for failed heroes.

QuestLogEntry:  [1010]
%qdt:
 _qgiver_ of ___qgiver_
 asked me to find _hermit_.
 Supposedly, _hermit_ has the
 answer to a riddle. The only clue
 I have is that %g once worked with
 _spouse_ in ___spouse_.

Message:  1011
<ce>               The _flowers_ were not really necessary.
<ce>                    _hermit_ left to study under the
<ce>                      famous teacher _teacher_ in
<ce>                    __school_. If you give %g2 this
<ce>                 book, %g may look upon you favorably.

Message:  1012
<ce>                    _hermit_ asked me not to reveal
<ce>                 %g3 whereabouts to strangers. However,
<ce>                      since you bring _book_ from
<ce>                   _spouse_, you are clearly not just
<ce>                    some stranger. _hermit_ secluded
<ce>                  %g2self in a dungeon to study arcane
<ce>                  lore. I have marked its location on
<ce>                       your map. Good luck, %pcn.

Message:  1013
<ce>                  I hate being bothered! If the only
<ce>                  way to get you to leave me alone is
<ce>                 to give you the answer to that stupid
<ce>                  riddle, then here, take it. Now get
<ce>                   out of here before I summon a fire
<ce>                      daedra to show you the way.

Message:  1014
Speak not of love or hate, but tell
 me this: what gift can you give to
 me that I can never buy for myself?

Message:  1015
On %qdt, I spoke with
 _spouse_. %g told me that
 _hermit_ left to
 study under _teacher_
 in __school_.

Message:  1016
On %qdt, I met with
 _hermit_'s teacher,
 _teacher_ of
 __school_. %g said that
 _hermit_ had secluded %g2self in
 ___dungeon_.

Message:  1017
Speak not of love or hate, but tell
 me this: what gift can you give to
 to me that I can never buy for myself?
 
 'It's KINDNESS, stupid!'


-- Symbols used in the QRC file:
--
--              %dat occurs 2 times.
--                %g occurs 12 times.
--               %g2 occurs 8 times.
--           %g2self occurs 3 times.
--               %g3 occurs 3 times.
--              %pcf occurs 1 time.
--              %pcn occurs 2 times.
--              %qdt occurs 1 time.
--               %ra occurs 2 times.
--       ___dungeon_ occurs 1 time.
--        ___qgiver_ occurs 1 time.
--        ___spouse_ occurs 4 times.
--         __school_ occurs 4 times.
--            _book_ occurs 1 time.
--         _flowers_ occurs 1 time.
--            _gold_ occurs 3 times.
--          _hermit_ occurs 12 times.
--          _qgiver_ occurs 8 times.
--          _spouse_ occurs 10 times.
--         _teacher_ occurs 3 times.

QBN:
Item _book_ book
Item _letter_ letter used 1014
Item _flowers_ yellow_flowers
Item _answer_ letter used 1017
Item _gold_ gold

Person _hermit_ face 1 group Group_7.2
Person _qgiver_ group Questor male
Person _spouse_ group Group_7.1 female
Person _teacher_ face 1 faction The_Academics

Place _dungeon_ remote dungeon
Place _school_ remote library

Clock _S.01_ 90.00:00
--removed flags to make timer exactly 90 days


--	Quest start-up:
	dialog link for location _school_ person _teacher_ 
	dialog link for location _dungeon_ person _hermit_ 
	start timer _S.01_ 
	log 1010 step 0 
	get item _flowers_ 
	get item _letter_ 
	create npc _spouse_ 
	place npc _hermit_ at _dungeon_ 
	place npc _teacher_ at _school_ 

variable _questdone_
_S.01_ task:
	end quest 

_S.02_ task:
	toting _flowers_ and _spouse_ clicked saying 1011 
	add dialog for location _school_ person _teacher_ 
	log 1015 step 1 
	get item _book_ 

_S.03_ task:
	toting _book_ and _teacher_ clicked saying 1012 
	add dialog for person _hermit_ 
	reveal _dungeon_ 
	log 1016 step 2 

_S.04_ task:
	toting _letter_ and _hermit_ clicked saying 1013 
	get item _answer_ 

_S.05_ task:
	toting _answer_ and _qgiver_ clicked 
	give pc _gold_ 
	end quest 
